求一个土与桩基作用的ansys命令流，有切分土体，还有处理土与桩基接触面问题的，十分谢谢。。。。

求一个土与桩基作用的ansys命令流，有切分土体，还有处理土与桩基接触面问题的，十分谢谢。。。。

给你一个参考用，是桩基的：

/prep7
et,1,plane42
et,2,solid45

mp,ex,1,2.5e10 !桩的弹性模量
mp,nuxy,1,0.2 !桩的泊松比
mp,dens,1,2500 !桩的密度
mp,ex,2,2.5e8 !土的弹性模量
mp,nuxy,2,0.4 !土的泊松比
mp,dens,2,2000 !土的密度
tb,dp,2
tbdata,1,19,32,30 !粘聚力c为19,摩擦角为32度,膨胀角为30

RECTNG,0,1,0,8, !面1
RECTNG,1,5,0,6, !面2
RECTNG,0,5,0,-16, !面3

/pnum,area,1
/pnum,line,1
asel,s,,,2,3,1
aglue,all
numcmp,all
allsel
aplot

lsel,s,,,1,3,2 !划分面1
lesize,all,,,2
lsel,s,,,2,4,2
lesize,all,,,16
amesh,1

lsel,s,,,6,8,2 !划分面2
lesize,all,0.5
lsel,s,,,5
lesize,all,0.5
lsel,s,,,7
lesize,all,0.5
amesh,2

lsel,s,,,11 !划分面3
lesize,all,0.5
lsel,s,,,12
lesize,all,0.5
lsel,s,,,10
lesize,all,0.5
lsel,s,,,9
lesize,all,0.5
amesh,3

EXTOPT,ESIZE,2,0, !拉伸成体1
EXTOPT,ACLEAR,1
type,2
mat,1
VEXT,1,,,,,-1

EXTOPT,ESIZE,2,0, !拉伸成体2，3
EXTOPT,ACLEAR,1
mat,2
VEXT,2,3,1,,,-1

allsel
/view,1,1,1,1
eplot

k,1001,5,6,-5
k,1002,5,0,-5
k,1003,5,-16,-5
l,18,1001
l,1001,1002
l,1002,17
l,1002,1003
l,1003,21
al,22,36,37,38 !面4和面5
al,30,38,39,40

EXTOPT,ESIZE,10,0,
EXTOPT,ACLEAR,1
VEXT,19,20,1,-5 !拉伸成体4和5
vplot

vsel,s,,,4,5,1
vplot
lsel,s,,,36,52,1
lesize,all,0.5
type,2
mat,2
vmesh,all !划分体4和5
allsel

vsel,s,,,2,5,1 !合并体2，3，4，5上的重复单元及节点
VPLOT
ESLV,S
NSLV,S,1
EPLOT
nummrg,all
numcmp,all
numcmp,all
allsel
/pnum,area,1
/view,1,1,1,1
/ang,1
/pnum,mat,1,2
eplot

!接触单元设置
allsel
et,3,170
et,4,173
keyopt,4,9,0
keyopt,4,12,2
r,10
real,10

mp,mu,2,0.2

vsel,s,,,1
vplot
asel,s,,,4,6,1
aplot
cm,target,area

type,3
nsla,s,1
esurf,all

esel,s,type,,3
eplot
/psyms,esys,1
allsel

vsel,s,,,2,5,1
vplot
asel,s,,,13
asel,a,,,17
asel,a,,,22
aplot
cm,contact,area

type,4
nsla,s,1
esurf,all
esel,s,type,,4
eplot
/psyms,esys,1
allsel
gplot

finish
/solu
asel,s,loc,x,0
aplot
DA,all,symm
asel,s,loc,x,5
DA,all,all
aplot
asel,s,loc,z,0
da,all,symm
asel,s,loc,z,-5
da,all,all
asel,s,loc,y,-16
da,all,all
allsel

ACEL,0,9.8,0,
nsel,s,loc,y,8
esln,s
eplot
sfe,all,3,pres,,50

antype,static
nlgeom,on
time,1
nsub,100
outres,all,all
allsel
solv

!南京 桩筏计算
!C section
! time 11/24/2002

fini
/cle

long = 12.763 !半承台长度 x方向
ww = 16.925 !半承台宽度 y方向
hh = 0.7 !承台高度

structheight = 7.6 ! 结构高度

pilelen = 40.5
pilediameter = 0.7088

!桩 x 方向发布坐标
*dim,px,array,4,1,1
px(1) = 1.763
px(2) = 3.5 + px(1)
px(3) = 3.45 + px(2)
px(4) = 3.45 + px(3)

!桩 y 方向发布坐标
*dim,py,array,4,1,1
py(1) = 1.725
py(2) = 3.45 + py(1)
py(3) = 3.3 + py(2)
py(4) = 3.3 + px(3)

!最边上5桩坐标
*dim,pxx,array,5,1,1
pyy5 = py(4) + 3.3 ! y 坐标
! x 坐标
pxx(1) = 0
pxx(2) = pxx(1) + 3.113
pxx(3) = pxx(2) + 3.05
pxx(4) = pxx(3) + 3
pxx(5) = pxx(4) + 3

cof = 0.9 !压缩模量转换成弹性模量的系数

! 桩顶为地基平面0标高
soilwidth = ww*1.5
soilnum = 7
*dim,soilthick,array,soilnum,1,1
*dim,soiles,array,soilnum,1,1
soilthick(1) = 0.36 !土层1厚度
soiles(1) = 2e6*cof !土层1模量
soilthick(2) = 0.6 !土层2厚度
soiles(2) = 5.6e6*cof !土层2模量
soilthick(3) = 9.7 !土层3厚度
soiles(3) = 2.9e6*cof !土层3模量
soilthick(4) = 10.2 !土层4厚度
soiles(4) = 2.3e6*cof !土层4模量
soilthick(5) = 3.4 !土层5厚度
soiles(5) = 3.1e6*cof !土层5模量
soilthick(6) = 5.3 !土层6厚度
soiles(6) = 4.3e6*cof !土层6模量
soilthick(7) = 17.8 !土层7厚度
soiles(7) = 8e6*cof !土层7模量

*dim,sbottom,array,soilnum,1,1
sbottom(1) =soilthick(1)
*do,i,2,soilnum
sbottom(i) =sbottom( i-1 ) + soilthick( i )
*enddo
soildeepth= sbottom(7) !计算深度

load1 = 1
load2 = 2
load3 = 3
load4 = 4

! pile and soil's component
!*dim,soilonly,array,soilnum+1,1,1
!*dim,pileonly,array,soilnum+1,1,1
!*do,i,1,soilnum+1
! soilonly(i) = i*10
! pileonly(i) = i*10+2
!*enddo

/prep7
bopt,numb,off

et,1,plane42
ET,2,SOLID45 !185

!* element property

mp,ex,30,2e10 !承台和桩
mp,prxy,30,0.167
mp,dens,30,2.5e3-1e3 ! !kg/m^3 补偿基础
mp,ex,20,1e12 ! water
mp,prxy,20,0.45
mp,dens,20,0.224e3
mp,ex,21,2e10 ! wall
mp,prxy,21,0.167
mp,dens,21,9.795e3
mp,ex,22,2e10 ! pillar
mp,prxy,22,0.167
mp,dens,22,115.8e3

*do,i,1,soilnum
MP,EX,i,soiles( i ) !土层 i
MP,PRXY,i,0.35
*enddo

!创建体
!BLOCK,0,long,0,ww,0,-hh, !承台
rect,0,long,0,ww
!cm,chentai,volu

*do,xx,1,4
*do,yy,1,4
!移动工作平面
!wprota,0,90,0
wpoffs,px( xx ),py( yy ),0
!创建桩
BLC5, 0, 0, pilediameter, pilediameter, 0
! BLC5, 0, 0, pilediameter, pilediameter, pilelen
!恢复工作平面
WPCSYS,-1
*enddo
*enddo

wpoffs,pxx( 1 )+pilediameter/4,pyy5,0
BLC5, 0, 0, pilediameter/2, pilediameter, 0
WPCSYS,-1
*do,xx,2,5
wpoffs,pxx( xx ),pyy5,0
BLC5, 0, 0, pilediameter, pilediameter, 0
WPCSYS,-1
*enddo

!土层
rect,0,long,0,ww !土层1
rect,long,soilwidth,0,ww
rect,0,long,ww,soilwidth
rect,long,soilwidth,ww,soilwidth

aptn,all
aglue,all
! mesh
mshape,1,2d
mshkey,0
smrt,10
lsel,s,loc,y,0
lsel,r,loc,x,0,ww
asll,s,0
asel,r,loc,z,0
cm,soilin,area
amesh,all
alls,all

lsel,s,loc,y,0
asll,s,0
asel,r,loc,z,0
cm,soilonly,area

mshape,0,2d
mshkey,1
alls
cmsel,s,soilin
asel,inve
AESIZE,all,pilediameter
lsel,s,loc,x,long+0.1,soilwidth-0.1
lsel,a,loc,y,ww+0.1,soilwidth-0.1
lesize,all,,,5
amesh,all
alls

!extrude the area to volume
TYPE,2 ! using element type 2, solid 3d element
! soil and pile
*do,i,1,soilnum
asel,s,loc,z,sbottom(i)-soilthick( i )
*if,i,lt,3,then
EXTOPT,ESIZE,1,0, ! size
*else
EXTOPT,ESIZE,3,0, ! size
*endif
MAT,i ! using material type i
*if,i,eq,soilnum,then
vext,all,,,0,0,pilelen - sbottom(soilnum-1)
asel,s,loc,z,pilelen
vext,all,,,0,0,sbottom(soilnum)-pilelen
*else
vext,all,,,0,0,soilthick( i )
*endif
*enddo
alls,all

asel,s,loc,y,0
asel,a,loc,y,soilwidth
asel,r,loc,z,0,sbottom(1)
vsla,s,0
cm,sv1,volu
asel,s,loc,y,0
asel,a,loc,y,soilwidth
asel,r,loc,z,sbottom(1),sbottom(2)
vsla,s,0
cm,sv2,volu
asel,s,loc,y,0
asel,a,loc,y,soilwidth
asel,r,loc,z,sbottom(2),sbottom(3)
vsla,s,0
cm,sv3,volu
asel,s,loc,y,0
asel,a,loc,y,soilwidth
asel,r,loc,z,sbottom(3),sbottom(4)
vsla,s,0
cm,sv4,volu
asel,s,loc,y,0
asel,a,loc,y,soilwidth
asel,r,loc,z,sbottom(4),sbottom(5)
vsla,s,0
cm,sv5,volu
asel,s,loc,y,0
asel,a,loc,y,soilwidth
asel,r,loc,z,sbottom(5),sbottom(6)
vsla,s,0
cm,sv6,volu
asel,s,loc,y,0
asel,a,loc,y,soilwidth
asel,r,loc,z,sbottom(6),pilelen
vsla,s,0
asel,a,loc,y,soilwidth
vsel,a,loc,z,pilelen,sbottom(7)
cm,sv7,volu

cmsel,s,sv1
cmsel,a,sv2
cmsel,a,sv3
cmsel,a,sv4
cmsel,a,sv5
cmsel,a,sv6
cmsel,a,sv7
vsel,inve
cm,piletotal,volu

!load
BLOCK,0,long,0,ww,0,-hh, !底板

wpoffs,0,0,-hh
block,long-0.225,long,0,pyy5,0,-structheight
cm,loadarea1,volu
!rect,0,long-0.225,ww-0.3,ww
!cm,loadarea2,area
block,0,long-0.225,pyy5-0.45,pyy5,0,-structheight
cm,loadarea3,volu
pillarwidth = 0.5
block,px(1)-pillarwidth/2,px(1)+pillarwidth/2,pyy5-11.5-pillarwidth/2,pyy5-11.5+pillarwidth/2,0,-structheight
!blc5,px( 1 ),pyy5-11.5,pillarwidth,pillarwidth
cm,pillarload,volu
block,0,long-0.225,0,pyy5-0.45,0,-structheight
wpcsys,-1

! clear soil 1's mesh
vsel,s,loc,z,0,sbottom(1)
vclear,all
vsel,s,loc,z,-hh-structheight,sbottom(1)
vptn,all
vglue,all

! material property
vsel,s,loc,z,-hh-structheight,-hh
asel,s,loc,y,0
asel,r,loc,z,-hh-structheight,-hh
asel,r,loc,x,0,long-0.225
vsla,s,0
cm,vwater,volu
vatt,20
vsel,s,loc,z,-hh-structheight,0
vsel,r,loc,x,px(1)-pillarwidth/2,px(1)+pillarwidth/2
vsel,r,loc,y,pyy5-11.5-pillarwidth/2,pyy5-11.5+pillarwidth/2
cm,vpillar,volu
vatt,22
vsel,s,loc,z,-hh-structheight,0
cmsel,u,vwater
cmsel,u,vpillar
cm,vwall,volu
vatt,21
alls
! remesh soil 1 by sweeping
mat,1
vsel,s,loc,z,0,sbottom(1)
vsweep,all

! material property
cmsel,s,piletotal
eslv,s
emodif,all,mat,30 ! change pile's material number to 30
alls

! mesh board
mshape,1,3d
mshkey,0
!smat,10
asel,s,loc,z,-hh
AESIZE,all,pillarwidth
vsel,s,loc,z,-hh,0
vmesh,all

mshape,1,3d
mshkey,0
!vsel,s,loc,z,-hh-structheight,-hh
lsel,s,loc,z,-hh-structheight+0.1,-hh-0.1
lesize,all,,,4
asel,s,loc,z,-hh-structheight
lsla,s
lesize,all,pillarwidth
vsel,s,loc,z,-hh-structheight,-hh
vmesh,all
!vsweep,all
alls

!constraint
asel,s,loc,x,0
asel,a,loc,y,0
da,all,symm
asel,s,loc,x,soilwidth
asel,a,loc,y,soilwidth
da,all,symm
asel,s,loc,z,soildeepth
da,all,all,0
alls
! load
acel,,,-9.8

! solve
/solu
alls
solve