下面这段批处理文件（opc组件注册）是啥意思，求逐句解释！

下面这段批处理文件（opc组件注册）是啥意思，求逐句解释！

帮您按段解释吧，我的解释都是双冒号打头的：
::下面这句是注释，就是屏蔽了原来的“关闭回显”语句，就当这句没用吧
rem @echo off
::下面这句就是显示各信息Register OPC Common ........
@ECHO Register OPC Common ........
::下面这段是将要用的文件考到windows目录的system32目录下
copy opcproxy.dll %WINDIR%\System32 /Y
copy opccomn_ps.dll %WINDIR%\System32 /Y
copy opc_aeps.dll %WINDIR%\System32 /Y
copy opchda_ps.dll %WINDIR%\System32 /Y
copy opcenum.exe %WINDIR%\System32 /Y
::转到操作系统的所在盘
%HOMEDRIVE%
::进入windows目录的system32目录
cd %WINDIR%\System32
::注册刚才拷贝的文件
REGSVR32 /s opcproxy.dll
REGSVR32 /s opccomn_ps.dll
REGSVR32 /s opc_aeps.dll
REGSVR32 /s opchda_ps.dll
::将opcenum注册为服务
opcenum -service
::等待用户确认
pause
::下面这句其实是为了空行，但是少写了一个.，所以会提示当前的回显状态
echo
::下面这一大段都是在写epcenum.reg这个注册表文件
echo Windows Registry Editor Version 5.00 >>opcenum.reg
echo [HKEY_CLASSES_ROOT\AppID\{13486D44-4821-11D2-A494-3CB306C10000}] >>opcenum.reg
echo @="OpcEnum" >>opcenum.reg
echo "LaunchPermission"=hex:01,00,04,80,38,00,00,00,54,00,00,00,00,00,00,00,14,00,\ >>opcenum.reg
echo 00,00,02,00,24,00,01,00,00,00,00,00,14,00,1f,00,00,00,01,01,00,00,00,00,00,\ >>opcenum.reg
echo 01,00,00,00,00,53,44,65,76,39,38,00,4e,01,05,00,00,00,00,00,05,15,00,00,00,\ >>opcenum.reg
echo a0,5f,84,1f,5e,2e,6b,49,ce,12,03,03,f4,01,00,00,01,05,00,00,00,00,00,05,15,\ >>opcenum.reg
echo 00,00,00,a0,5f,84,1f,5e,2e,6b,49,ce,12,03,03,f4,01,00,00 >>opcenum.reg
echo 02,00,00 >>opcenum.reg
echo "AccessPermission"=hex:01,00,04,80,38,00,00,00,54,00,00,00,00,00,00,00,14,00,\ >>opcenum.reg
echo 00,00,02,00,24,00,01,00,00,00,00,00,14,00,07,00,00,00,01,01,00,00,00,00,00,\ >>opcenum.reg
echo 01,00,00,00,00,3a,5c,50,72,6f,67,72,61,01,05,00,00,00,00,00,05,15,00,00,00,\ >>opcenum.reg
echo a0,5f,84,1f,5e,2e,6b,49,ce,12,03,03,f4,01,00,00,01,05,00,00,00,00,00,05,15,\ >>opcenum.reg
echo 00,00,00,a0,5f,84,1f,5e,2e,6b,49,ce,12,03,03,f4,01,00,00 >>opcenum.reg
echo "AuthenticationLevel"=dword:00000001 >>opcenum.reg
echo "RunAs"="Interactive User" >>opcenum.reg
echo "ServiceParameters"="-Service" >>opcenum.reg
::下面这句相当于等待1秒
ping 127.0.0.1 -n 1 >nul
::完成opcenum.reg向注册表的添加
@regedit /s opcenum.reg
::删除opcenum.reg
del /Q opcenum.reg 2>nul
::删除系统临时文件路径下opc打头的所有文件
del /Q %temp%\opc*.* >2nul
::退出
exit