谁有卡西欧5800的公路测量程序
- 提问者网友：藍了天白赴美
- 2021-04-21 23:06
- 五星知识达人网友：迟山
- 2021-04-22 00:00
*******************************************************************************************************
【分段线路坐标正反算程序】
主 程 序：【XLZB-FD】
L1: Ø.1739274226→B:Ø.5-B→C:1→U:"1.KD→XY 2.XY→KD"?U:If U=1:Then Prog "ZS-FD":Else Prog "FS-FD":IfEnd↙
子程序1：【ZS-FD】
L1: Ø→Z:9Ø→V↙
L2: Lbl Ø:"K"?K:Prog "ZZ-FD":If U≠Ø:Then Goto Ø:IfEnd:"K.D"?Z:If Z≠Ø:Then "K.A"?V:F+V→F:S+Zcos(F)→S:T+Zsin(F)→T:IfEnd↙
L3: Fix 3:"K.X=":S◢
L4: "K.Y=":T◢
L5: Norm:Goto Ø↙
子程序2：【FS-FD】
L1: Lbl 2:{VW}:"K.X"?V:"K.Y"?W:Ø→K↙
L2: Lbl 3:Prog "ZZ-FD":V-S→I:W-T→J:Pol(I,J):J-F→J:K+Rec(I,J)→K:If Abs(I)<1m:Then Fix 3:"K=":K◢:"K.D=":J◢
L3: Norm:Else Goto 3:IfEnd↙
L4: 1→M:"Ø.NEXT 1.EXIT"?M:If M=Ø:Then Goto 3:IfEnd:Goto 2↙
子程序3：【ZZ-FD】
L1: Prog "DATA-FD":K-L→M:(P-R)÷2PQR→O:5→DimZ:Ø.Ø694318442→Z[1]:Ø.33ØØØ94782→Z[2]:1→Z[3]:1-Z[3]→Z[4]:1-Z[2]→Z[5]↙
L2: For 1→I to 5:A+MrZ[I](1÷P+OMZ[I])→Z[I]:Next:Z[3]→F↙
L3: X+M(Bcos(Z[1])+Ccos(Z[2])+Ccos(Z[4])+Bcos(Z[5]))→S↙
L4: Y+M(Bsin(Z[1])+Csin(Z[2])+Csin(Z[4])+Bsin(Z[5]))→T↙
子程序4：【DATA-FD】
L1: Ø→U:If K<(线路起点里程):Then "<<!":1→U:IfEnd:If K>(线路终点里程):Then ">>!":1→U:IfEnd↙
L2: (线元起点里程)→Q:If K≤L+Q:Then (线元起点半径)→P:(线元终点半径)→R:(线元起点X坐标)→X:(线元起点Y坐标)→Y:(线元起点方位角)→A:Goto E:IfEnd:L+Q→L↙
L3: (重复L2）
L4: Lbl E↙
输入说明： L2开始每行程序为一个线元参数要素，有几个线元就输入几行。
直线半径按<1E45>输入。
功能常数可能位置会不同，请仔细查询；
<m>位于<Function－1－▽▽▽▽－1；
<r>位于<Function－5－5>；<e>位于<EXP>键；
<Dsz>位于<Function－3－6>。
*******************************************************************************************************
【完整线路坐标正反算程序】
主 程 序：【XLFY-ALL】
L1: 5→DimZ:1→Z:"1.KD→XY 2.XY→KD"?Z:If Z=1:Then Prog "ZS-ALL":Else Prog "FS-ALL":IfEnd↙
子程序1：【ZS-ALL】
L01: Z→Ø:V→9Ø↙
L02: Lbl Ø:"K"?K:Prog "ZZ-ALL":If Z[1]≠Ø:Then Goto Ø:IfEnd:"K.D"?Z:If Z≠Ø:Then "K.A"?V:F+V→F:X+Zcos(F)→X:Y+Zsin(F)→Y:IfEnd↙
L03: Fix 3:"K.X=":X◢
L04: "K.Y=":Y◢
L05: Norm:Goto Ø↙
子程序2：【FS-ALL】
L01: Lbl 8:"K.X"?V:"K.Y"?W:Ø→K↙
L02: Lbl 9:Prog "ZZ-ALL":V-X→I:W-Y→J:Pol(I,J):J-F→J:K+Rec(I,J)→K:If Abs(I)<1m:Then Fix 3:"K=":K◢:"K.D=":J◢
L03: Norm:Else Goto 9:IfEnd↙
L04: 1→Z:"Ø.NEXT 1.EXIT"?Z:If Z=Ø:Then Goto 9:IfEnd:Goto 8↙
子程序3：【ZZ-ALL】
L01: Prog "DATA-ALL":Abs(B)πR÷18Ø-(L+M)÷2→G↙
L02: L²÷24÷R-L^4÷2688÷R^3→P:L÷2-L^3÷24Ø÷R²→Q↙
L03: M²÷24÷R-M^4÷2688÷R^3→U:M÷2-M^3÷24Ø÷R²→O↙
L04: (R+U-(R+P)cos(Abs(B)))÷sin(Abs(B))+Q→T:(R+P-(R+U)cos(Abs(B)))÷sin(Abs(B))+O→S:J-T+1m→D↙
L05: If K≤D:Then Goto 1:IfEnd:If K≤D+L:Then K-D→C:L→U:Goto 2:IfEnd:If K≤D+L+G:Then 1→C:Goto 3:IfEnd:If K≤D+M+L+G:Then K-D-M-L-G→C:M→U:Goto 2:IfEnd:If K>D+M+L+G:Then K-D-L-M-G→C:Goto 5:IfEnd↙
L06: Lbl 1:E+(J-K)cos(A+18Ø)→X:N+(J-K)sin(A+18Ø)→Y:A→F:Goto E↙
L07: Lbl 2:C-C^5÷(4ØR²U²)+C^9÷(3456R^4U^4)→H:C^3÷(6RU)-C^7÷(336R^3U^3)+C^11÷(4224ØR^5U^5)→I:If C=K-D:Then Goto 4:IfEnd:Goto 6↙
L08: Lbl 3:9Ø(2K-2D-L)÷π÷R→U:Rsin(U)+Q→H:R(1-cos(U))+P→I↙
L09: Lbl 4:If B<Ø:Then -I→I:IfEnd:E+Tcos(A+18Ø)+Hcos(A)+Icos(A+9Ø)→X:N+Tsin(A+18Ø)+Hsin(A)+Isin(A+9Ø)→Y:Goto 7↙
L10: Lbl 5:A+B→F:E+(C+S)cos(F)→X:N+(C+S)sin(F)→Y:Goto E↙
L11: Lbl 6:If B>Ø:Then -I→I:IfEnd:E+(S+H)cos(A+B)+Icos(A+B+9Ø)→X:N+(S+H)sin(A+B)+Isin(A+B+9Ø)→Y↙
L12: Lbl 7:R→U:If B<Ø:Then -R→U:IfEnd:If C=K-D:Then A+9ØC²÷(πUL)→F:IfEnd:If C=K-D-L-M-G:Then A+B-9ØC²÷(πUM)→F:IfEnd:If C=1:Then A+18Ø(K-D-L÷2)÷π÷U→F:IfEnd↙
L13: Lbl E↙
子程序4：【DATA-ALL】
L1: Ø→Z[1]:If K<(线路起点里程):Then "<<!":1→Z[1]:IfEnd:If K>(线路终点里程):Then ">>!":1→Z[1]:IfEnd↙
L2：If K≤(起点或上一段曲线缓直点里程):Then (交点里程)→J:(交点X坐标)→E:(交点Y坐标)→N:(半径)→R:(第一缓和曲线长度)→L:(第二缓和曲线长度)→M: (偏角)→B:(起始边方位角)→A:Goto E:IfEnd ↙
L3：（重复L2）
L4：Lbl E
简要说明：每行程序为一个曲线的参数要素，有几个曲线就输入几行。
*******************************************************************************************************
【中桩标高计算程序】
主 程 序：【H-SJ】
L1: Lbl Ø:"K"?K:Prog "DATA-H"↙
L2: Abs(R(G-F))÷200→T↙
L3: If K≤N-T:Then O-0.01F(N-K)→S:Goto 1:IfEnd↙
L4: If K≤N:Then O-0.01F(N-K)-(T+K-N)^2÷R÷2→S:Goto 1:IfEnd↙
L5: If K≤N+T:Then O-0.01G(N-K)-(T+N-K)^2÷R÷2→S:Goto 1:IfEnd↙
L6: If K>N+T:Then O-0.01G(N-K)→S:IfEnd↙
L7: Lbl 1:Fix 3:"H=":S◢Norm:Goto Ø↙
子程序4：【DATA-SJ】
L1: Ø→Z:If K<(线路起点里程):Then "<<!":1→Z:IfEnd:If K>(线路终点里程):Then ">>!":1→Z:IfEnd↙
L2：If K≤(起点或上一段竖曲线终止里程):Then (变坡点里程)→N:(变坡点高程)→O:(竖曲线半径<凸+ 凹->)→R:(前纵坡值)→F:(后纵坡值)→G:Goto E:IfEnd↙
L3：(重复L2)
L4：Lbl E
*******************************************************************************************************
【坡脚宽度计算程序】
程序名：【PJD】
L1: 25→L:2.5→G:1.5→T:8→N:0.9→A:0.9→B:1.10→C:1.5→D:"H-SJ"?S↙
L2: Lbl 1:"H-DM"?M:Abs(S-M)→H↙
L3: If S-M≥0:Then L+HD→K:Goto 2:IfEnd↙
L4: If H≤N:Then L+G+HA→K:Goto 2:IfEnd↙
L5: If H≤2N:Then L+G+NA+T+(H-N)B→K:Goto 2:IfEnd↙
L6: If H>2N:Then L+G+NA+T+NB+T+(H-2N)C→K:Goto 2:IfEnd↙
L7: Lbl 2:Fix 3:"L-PJ=":K◢↙
L8: Norm:Goto 1↙
*******************************************************************************************************
【坐标反算程序】
程序名：【XY-DF】
L1: Ø→I:Ø→J:"A.X"?D:"A.Y"?G:"B.X"?X:"B.Y"?Y:Pol((X-D),(Y-G)):If J<Ø:Then J+36Ø→J:IfEnd↙
L2: Fix 5:"AB-AZIMUTH=":J◢
L3: Fix 3:"AB-DIST=":I◢
L4: Norm↙
*******************************************************************************************************
【坐标正算程序】
程序名：【DF-XY】
L1: "A.X"?D:"A.Y"?G:"AB-AZIMUTH"?J:"AB-DIST"?I↙
L2: Fix 3:"B.X=":D+Icos(J)→X◢
L3: "B.Y=":G+Isin(J)→Y◢
L4: Norm↙
*******************************************************************************************************
【面积计算程序】
程序名：【AREA】
L1: Lbl Ø:"M"?M:"N"?N:M→E:N→F:Ø→S↙
L2: Lbl 1:"X"?X:"Y"?Y:S-(XN-YM)÷2→S:If X=E:Then If Y=F:Then "AREA=":Abs(S)→S◢ Goto Ø:IfEnd:IfEnd↙
L3: X→M:Y→N:Goto 1↙
*******************************************************************************************************
【两直线交点计算程序】
程序名：【JD】
L1: "1.X"?A:"1.Y"?B:"2.X"?C:"2.Y"?D:"3.X"?E:"3.Y"?F:"4.X"?G:"4.Y"?H↙
L2: C-A→N:D-B→O:G-E→P:H-F→Q:QN-OP→K:NB-OA→U:PF-QE→V↙
L3: Fix 3:"P.X=":(PU-NV)÷K→X◢↙
L4: "P.Y=":(QU-OV)÷K→Y◢
L5: Norm↙
*******************************************************************************************************
【点到直线距离计算程序】
程序名：【PLDIST】
L1: "P.X"?A:"P.Y"?B:"L1.X"?E:"L1.Y"?F:"L2.X"G:"L2.Y"?H↙
L2: Pol((G-E),(H-F)):J-90→J↙
L3: A+10cos(J)→C:B+10sin(J)→D↙
L4: C-A→N:D-B→O:G-E→P:H-F→Q:QN-OP→K:NB-OA→U:PF-QE→V↙
L5: (PU-NV)÷K→X:(QU-OV)÷K→Y:Pol((X-A),(Y-B))↙
L6: Fix 3:"AB-DIST=":I◢
L7: Norm↙